Kiosk Mode

HCL Nomad Kiosk Mode (different than HCL Notes Kiosk Mode) allows a specific database to be identified to always run on startup and not be allowed to be closed. Additionally, other aspects of HCL Nomad may be hidden or otherwise controlled with the provided settings.

Note: Kiosk Mode is a user interface feature designed to control the presentation of the application and other visual aspects of HCL Nomad. Kiosk Mode is not a security feature.
For Kiosk Mode to be enabled, two criteria must be met:
  • The database that will be used as the kiosk database must has a kioskDB profile document that specifies the kiosk mode settings.
  • The HCL Nomad client must have the kioskDBName notes.ini pointing to the kiosk database.

kioskDB Profile Document

For the database to be used in Kiosk Mode, the database must have the kioskDB profile document. There are many ways to create the profile document, but one way is to use an agent such as the following:

Sub Initialize
	' Create or update the HCL Nomad Kiosk Mode Profile ('kioskDB') document
	' from the current database.
	'
	' Besides the database having the 'kioskDB' profile document, to enable
	' Kiosk mode you must set the notes.ini variable named 'kioskDBName' to the
	' path and name of the database. Just the presence of the profile
	' document is not enough.
	'
	' When the database is found and the profile document exists, the named
	' database will open automatically and cannot be closed. Other behaviors
	' are defined by the items in the profile document.

	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim profile As NotesDocument

	Set db = session.CurrentDatabase
	Set profile = db.GetProfileDocument("kioskDB", "")

	' To be true, values can be "1", 1, or "yes". Otherwise, false is assumed.
	' All of the following items have defaults, so you should specify them.

	' Hide Application Menus (1 = hide, 0 = show)
	Call profile.ReplaceItemValue("HideAppMenu", "0")

	' Hide Help Menus (1 = hide, 0 = show)
	Call profile.ReplaceItemValue("HideHelpMenu", "0")

	' Hide Sametime Icon (1 = hide, 0 = show)
	Call profile.ReplaceItemValue("HideSametime", "1")

	' Open the Workspace (1 = open, 0 = do not open)
	Call profile.ReplaceItemValue("OpenWorkspace", "1")

	' Hide properties panel (1 = hide, 0 = show)
	Call profile.ReplaceItemValue("HidePropertiesPanel", "1")

	' All of the following items are optional, so you should only specify them
	' if you need to change them. LogoText and LogoIcon are mutually
	' exclusive, so only use one or the other. The icon can include text and
	' graphics, so if you want both, use only LogoIcon here and put the text
	' in the icon itself. If you specify both, LogoIcon wins (LogoText is
	' ignored).

	' Replace the application name with this text
	' Call profile.ReplaceItemValue("LogoText", "My App Name")

	' Replace the application icon with this resource
	' Call profile.ReplaceItemValue("LogoIcon", "$DBIcon")

	Call profile.Save(True, False)

	Print "HCL Nomad Kiosk Mode profile document ('kioskDB') saved successfully."
End Sub

The comment for each profile.ReplaceItemValue() indicates the available options and possible values.

If you ever wanted to remove the profile document, you might want to use this agent:

Sub Initialize
	' Remove the HCL Nomad Kiosk Mode Profile ('kioskDB') Document
	' from the current database.
	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim profile As NotesDocument
	
	Set db = session.CurrentDatabase
	Set profile = db.GetProfileDocument("kioskDB", "")
	Call profile.Remove(True)
	
	Print "HCL Nomad Kiosk Mode profile document ('kioskDB') removed successfully."
End Sub

kioskDBName notes.ini

The client must be configured to use the Kiosk database by setting the kioskDBName value in the notes.ini file. Setting notes.ini values describes several ways to accomplish this task.

If the Kiosk database is located on a server, the notes.ini value should use the server!!pathname format. For example:

CN=myserver/O=mydomain!!AppDirectory/KioskApp.nsf

If you want to use a local replica as the Kiosk database, the notes.ini value should use the local file path format. For example:

/data/KioskApp.nsf