GetEntryByUNID (NotesCalendar - LotusScript®)

Gets a calendar entry given its universal identifier (UNID).

Defined in

NotesCalendar

Syntax

Set notesCalendarEntry = notesCalendar.GetEntryByUNID( unid$ )
Parameter Description
unid String. The universal identifier (UNID) of the Domino® document containing the entry.
Return value Description
NotesCalendarEntry The calendar entry. An exception occurs if the identifier is invalid.

Examples

This agent gets a calendar entry using the UNID for a document from the ($Calendar) view in the mail database of the current user.
Sub Initialize
	Dim session As New NotesSession
	Dim maildb As New NotesDatabase("", "")
	Dim calview As NotesView
	Dim caldoc As NotesDocument
	Dim unid As String
	Dim cal As NotesCalendar
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim body As NotesRichTextItem
	Dim s As String
	Dim n As long
	REM Get calendar for current user
	Call maildb.Openmail()
	Set cal = session.getCalendar(maildb)
	Set db = session.CurrentDatabase
	REM Get number of calendar entry
	s = InputBox("Enter an integer", "calentry", 1)
	If IsNumeric(s) Then
		n = Clng(s)
	Else
		MessageBox "Not numeric: " & s,, "Error"
	End If
	REM Create document to post results
	Set doc = db.CreateDocument
	doc.Form = "main"
	doc.Subject = "Calendar entry"
	Set body = doc.Createrichtextitem("body")
	REM Get entry and put in body of document
	Set calview = maildb.Getview("($Calendar)")
	Set caldoc = calview.Getnthdocument(n)
	If caldoc Is Nothing Then
		body.Appendtext("Calendar entry out of range")
	Else
		unid = caldoc.Universalid
		body.Appendtext("Calendar entry for UNID " & unid)
		body.Addnewline(1)
		body.Appendtext(cal.Getentrybyunid(unid).Read())
	End If
	Call doc.Save( True, True )
End Sub